Скрипт AutoDriver'а для GTA San Andreas

Краткое описание

Этот рулезный скрипт заставляет CJ отправится в точку назначения на машине самому (то есть без какого-либо вмешательства в вашей строны... ну... почти без вмешательства ;) ), поставив метку на карте (RMB или T в меню карты).

Управление, оно же подробное описание

Z - включает/выключает автодрайвер
A - обновляет координаты метки на карте (также бывает полезным, когда машина остановилась по какой-то причине)
X - переключает поведение автодрайвера на послушного и не очень (игнорит светофоры, объезжает препятствия, ездит по встречке - включено по умолчанию).
Shift (Both) - включает режим драйв-бай (нужно нажать и держать, отпускание выключает). Можно стрелять из машины, скорость игры уменьшается в 2 раза. Баг: камера очень непослушная - возвращается в изначальное положение. Зато работает не только в режиме драйв-бай, а когда угодно и не конфликтует с оным. ;)
Spacebar - появляется статус текст, отображающий текущую максимальную скорость машины. Клавишами Вверх, Вниз можно повышать и понижать ее. Наверно, разберетесь.

Машина ведет себя на дороге несколько "умнее" остальных участников движения :) . Так называемое "качество вождения" улучшено в 2 раза (повышенная проходимость, тормозимость, поворачиваемость). Так же смещен центр масс вниз - она лучше проходит повороты, не переворачиваясь. Если это все же случится, она перевернется обратно.

Технические требования

Скрипт требует установленной игры GTA San Andreas v1.00 us (Наверно возможны другие версии, но в этом случае полная и даже частичная работоспособность скрипта не гарантируется), а также библиотеки CLEO v3.0.950 или выше. Если вы не знаете, что такое CLEO, отправляйтесь на http://sannybuilder.com за подробной информацией, библиотекой CLEO, разными фенечками к ней в виде плагинов и лучшим компилятором скриптов для серии трехмерных игр GTA всех времен и народов - Sanny Builder версии 3 (может выше), а также за форумом тех. поддержки.

Сырцы, они же исходники скрипта для изучения любопытствующим

{$CLEO}
30@ = 0
4@ = 25.0
while true
     wait 0   
     if
      player.Defined($PLAYER_CHAR)
     then  
         if and
          Actor.Driving($PLAYER_ACTOR)
          not Actor.DrivingVehicleType($PLAYER_ACTOR, #FREIGHT)
          not Actor.DrivingVehicleType($PLAYER_ACTOR, #STREAK)
          84A7:   not actor $PLAYER_ACTOR driving_boat  
          84C8:   not actor $PLAYER_ACTOR driving_flying_vehicle  
         then   
          03C0: 0@ = actor $PLAYER_ACTOR car
             if
              0AB0:   key_pressed 90          //Z
             then
              if and
               056E:   car 0@ defined  
               0AB6: store_target_marker_coords_to 1@ 2@ 3@ // IF and SET    
              then
               018C: play_sound 1058 at 0.0 0.0 0.0  
               if
                30@ == 0
               then
                gosub @car_drive_to
               else
                gosub @return_control
               end
              end
             0AB1: call_scm_func @release_key 1  90      //Z
             end
             if  
              22@ == 0
              0ab0: 16         //Shift
             then
               0470: 21@ = actor $PLAYER_ACTOR current_weapon  
               if and
                21@ >= 22
                21@ <= 32
               then
                gosub @drive_by_on
               end
             end  
             if
              22@ <> 0
             then
              if
               0ab0: 16         //Shift
              then
              else
               gosub @drive_by_off
              end
             end  
         end
         if
          30@ == 1
         then
             if or
              00E1:   player 0 pressed_key 15               //enter/exit ~k~~VEHICLE_ENTER_EXIT~  
              02BF:   car 0@ sunk
              0119:   car 0@ wrecked  
             then   
              gosub @return_control
             end
             if and
              056E:   car 0@ defined  
              01F4:   car 0@ flipped  
             then
              gosub @reflip_car
             end
             if
              856E:   not car 0@ defined  
             then
              30@ = 0
             else
                 if
                  not actor.InCar($PLAYER_ACTOR,0@)
                 then
                  30@ = 0
                 end
                 if and
                  0AB0:   key_pressed 65                           //A
                  0AB6: store_target_marker_coords_to 1@ 2@ 3@ // IF and SET    
                 then
                  gosub @refresh_coords
                  0AB1: call_scm_func @release_key 1  65          //A
                 end  
                 if
                  0ab0:32                  //spacebar
                 then
                  054C: use_GXT_table 'FTRAIN'  
                  if
                  29@ == 0
                  then
                  0AB1: call_scm_func @AddStatusText 4 VARNUMBER = 10 TYPE = 1 GXT = @StatusText LINE = 3
                  29@ = 1
                  end                  
                  gosub @dec_inc_speed
                 else
                  if  
                   29@ == 1
                  then
                   29@ = 0
                   0AB1: call_scm_func @RemoveStatusText 1 VARNUMBER = 10  
                  end  
                 end
                 if
                  01AE:   car 0@ sphere 0 near_point 1@ 2@ radius 3.0 3.0 stopped  
                 then
                   gosub @return_control
                 end
                 if
                  0ab0: 88                    //X
                 then
                  gosub @change_behaviour
                  0AB1: call_scm_func @release_key 1  88              //X
                 end
             end
         else
          if                    
           29@ == 1                    
          then                    
           29@ = 0                    
           0AB1: call_scm_func @RemoveStatusText 1 VARNUMBER = 10       
          end                    
         end
     end   
end       
           
:return_control
30@ = 0
072A: put_actor $PLAYER_ACTOR into_car 0@ driverseat  
0423: set_car 0@ improved_handling_to 1.0 // (float)  
car.RemoveReferences(0@)
03AB: unknown_car 0@ flag 0  
018C: play_sound 1058 at 0.0 0.0 0.0  
return  

:reflip_car
0174: 5@ = car 0@ Z_angle  
00AA: store_car 0@ position_to 6@ 7@ 8@  
00AB: put_car 0@ at 6@ 7@ 8@  
0175: set_car 0@ Z_angle_to 5@  
return

:car_drive_to
30@ = 1
02CE: 3@ = ground_z_at 1@ 2@ 3@  
Car.SetDriverBehaviour(0@, Nowhere)
00AE: set_car 0@ traffic_behaviour_to 2                   
0423: set_car 0@ improved_handling_to 2.0 // (float)  
03AB: unknown_car 0@ flag 1  
Car.DriveTo(0@, 1@, 2@, 3@)
Car.SetMaxSpeed(0@, 4@)
20@ = 0
return  

:refresh_coords
02CE: 3@ = ground_z_at 1@ 2@ 3@  
Car.DriveTo(0@, 1@, 2@, 3@)
018C: play_sound 1058 at 0.0 0.0 0.0  
return

:dec_inc_speed
if and
  4@ > 3.5  
  0ab0: 40
  32@ >= 75
then
  32@ = 0
  4@ += -0.5
  car.SetMaxSpeed(0@,4@)
end
if and
  4@ < 50.0  
  0ab0: 38
  32@ >= 75
then
  32@ = 0
  4@ += 0.5
  car.SetMaxSpeed(0@,4@)
end
0092: 10@ = float 4@ to_integer
10@ *= 2  
return

:change_behaviour
if
  20@ == 0
then
  20@ = 1
  00AE: set_car 0@ traffic_behaviour_to 1                   
  Car.SetDriverBehaviour(0@, FollowRoad)
else
  20@ = 0
  00AE: set_car 0@ traffic_behaviour_to 2                   
Car.SetDriverBehaviour(0@, Nowhere)
car.DriveTo(0@,1@,2@,3@)
end  
018C: play_sound 1058 at 0.0 0.0 0.0  
return

:drive_by_on
22@ = 1
0713: actor $PLAYER_ACTOR driveby_actor -1 car -1 point 0.0 0.0 0.0 radius 300.0 8 0 firing_rate 75  
015D: set_gamespeed 0.5
return

:drive_by_off
22@ = 0
072A: put_actor $PLAYER_ACTOR into_car 0@ driverseat  
if
30@ == 1
then
repeat
wait 0
until actor.InCar($PLAYER_ACTOR,0@)
car.DriveTo(0@,1@,2@,3@)
end
015D: set_gamespeed 1.0
return

:release_key
while 0ab0: 0@
wait 0
end
0AB2: ret 0

:AddStatusText                  
0AB1: call_scm_func @__VarToOffset 1 0@ 0@
0AB1: call_scm_func @__LabelToOffset 1 2@ 2@
0AA6: call_method 0x0044CDA0 struct 0x00BA1788 num_params 4 pop 0 ( LINE = 3@ GXT = 2@ TYPE = 1@ VARNUMBER = 0@ )
0AB2: ret 0

:RemoveStatusText
0AB1: call_scm_func @__VarToOffset 1 0@ 0@
0AA6: call_method 0x0044CE80 struct 0x00BA1788 num_params 1 pop 0 ( VARNUMBER = 0@ )
0AB2: ret 0

:__VarToOffset
0A9F: 1@ = current_thread_pointer
0A8E: 2@ = 1@ + 0xDC // mission Flag
0A8D: 2@ = read_memory 2@ size 1 virtual_protect 0
if
     2@ == 1
then
     1@ = 0x00A48960 // mission locals
else
     1@ += 0x3C
end
0@ *= 4
005A: 1@ += 0@ // address of the local variable  
1@ -= 0xA49960
0AB2: ret 1 1@

:__LabelToOffset
if
     0@ == 0
then
     0AB2: ret 1 0
end
0A9F: 1@ = current_thread_pointer
1@ += 0x10  
0A8D: 1@ = read_memory 1@ size 4 virtual_protect 0 // baseIP
0062: 1@ -= 0@ // label address
1@ += 3
0AB2: ret 1 1@

:StatusText
0900: 'FREI_11'
0000:

Авторство и прочая ерунда, которую можно не читать

Автором (человеком, известным под ником Alien), как ни странно, является тот, кто написал скрипт и сию чтиву.
Автор не несет отвественности за возможные потери информации на вашем компьютере, а также ущерб неокрепшей психике и здоровью, могущий возникнуть, вероятно, от чрезмерного сидения за компьютерными играми. (А что все так пишут, вот и я написал))).
Скрипт написан для пользователей сайта http://scriptsforgta.net.ru, наличие ссылки на который и наличие данного документа в архиве со скриптом обязательны при его размещении на другом ресурсе.